//定義變數
var testId:int = 1;
var testName:String = "Flash";
var testVer:String = "cs3";
var testTagName:String = "testxml";
var testTagAttr:String = "other";
		
//利用isXMLName()檢查字串是否可當作標籤或屬性名稱
if ( isXMLName(testTagName) && isXMLName(testTagAttr) ){
	//以下將建立3個xml物件(xml,xml2,xml3)
	var xml:XML=
		<testxml>
			<item id={testId}>
				<{testTagName} {testTagAttr}="ok">{testName}</{testTagName}>
				<price>{testVer}</price>
			</item>
		</testxml>

	var xml2Str:String=
		"<testxml2>"+
			"<item id=\""+testId+"\">"+
			"<"+testTagName+" "+testTagAttr+"=\"ok\">"+testName+"</"+testTagName+">"+
			"<price>"+testVer+"</price>"+
			"</item>"+
		"</testxml2>";
	var xml2:XML = new XML(xml2Str);

	var arrays:Array =
		[{name:"Flash",ver:"cs3"},
	 	{name:"Java",ver:"1.6.2.0"}];
	var xml3:XML = <testxml3 />
	for (var i:int=0;i<arrays.length;i++){
		var addNode:XML = 
			<item>
				<name>{arrays[i].name}</name>
				<ver>{arrays[i].ver}</ver>
			</item>
		xml3.appendChild(addNode);
	}

	output_txt.text = xml+xml2+xml3;

}else{

	output_txt.text = "error";

}
	
※蘭さん：一開始使用的isXMLName()，是用來檢查字串是否符合xml格式，像是【4test】，這就是不合法的格式。

※蘭さん：第一個xml物件中，是最基本的建立方式，並且使用{變數名稱}來區別變數。

※蘭さん：第二個xml物件則是先建立字串後，再將字串轉為xml物件。

※蘭さん：第三個xml物件則利用array和for迴圈來建立xml物件，並利用appendChild()插入節點來擴充物件。

※蘭さん：最後再將3個xml輸出到output_txt

//output_txt輸出結果
<testxml>
  <item id="1">
    <testxml other="ok">Flash</testxml>
    <price>cs3</price>
  </item>
</testxml>
<testxml2>
  <item id="1">
    <testxml other="ok">Flash</testxml>
    <price>cs3</price>
  </item>
</testxml2>
<testxml3>
  <item>
    <name>Flash</name>
    <ver>cs3</ver>
  </item>
  <item>
    <name>Java</name>
    <ver>1.6.2.0</ver>
  </item>
</testxml3>